Gergonne Point of a Triangle

gergonne.html

Exploration

Let , and be the points of contact of the inscribed circle of with sides , and , respectively. Show that lines , and are concurrent.  The point of concurrency is called the Gergonne Point of the triangle after J.D. Gergonne (1771–1859), founder-editor of the mathematics journal Annales de Mathematiques.

Approach

Create the triangle in a simplified position and construct the inscribed circle. Construct the tangency points and the prescribed lines. Show that the lines are concurrent.

Initialize

To initialize Descarta2D, select the input cell bracket and press SHIFT-Enter.

This initialization assumes that the Descarta2D software has been copied into one of the standard directories for AddOns which are on the Mathematica search path, $Path.

<<Descarta2D`

Solution

Without loss of generality, create the triangle's vertex points and the triangle itself in a convenient position.

Clear[a,b];
P1=Point2D[0,0];
P2=Point2D[a,b];
P3=Point2D[1,0];
T1=Triangle2D[P1,P2,P3];

Construct the circle inscribed in the triangle.

C1=Circle2D[T1,Inscribed2D] //FullSimplify;

Construct the lines through the sides of the triangle.

{L12=Line2D[P1,P2],L13=Line2D[P1,P3],L23=Line2D[P2,P3]}

Construct tangency points which are the poles of the sides with respect to the inscribed circle.

{Q12,Q13,Q23}=
   Map[FullSimplify,
       {Point2D[L12,C1],Point2D[L13,C1],Point2D[L23,C1]}];

Construct the lines defining the Gergonne point.

{L1,L2,L3}=
   Map[FullSimplify,
       {Line2D[P1,Q23],Line2D[P2,Q13],Line2D[P3,Q12]}];

The three lines are concurrent if the determinant of their coefficients is zero.

Det[{List@@L1, List@@L2, List@@L3}] //FullSimplify

Discussion

This plots a numerical example with specific points.

Sketch2D[{P1,P2,P3,T1,C1,Q12,Q13,Q23,L1,L2,L3,
          Point2D[L1,L2]} //. {a->2/3,b->1},
   PlotRange->{{-0.25,1.25},{-0.25,1.25}}]

Graphics saved as "gergon01.eps".