Monge's Theorem

monge.html

Exploration

Given three circles and the external tangent lines of the circles taken in pairs, show that the three intersection points of the three tangent pairs lie on a straight line.

Approach

Construct the three circles in a simplified position (without loss of generality). Construct the intersection point of the tangent pairs of lines. Show that the points are collinear.

Initialize

To initialize Descarta2D, select the input cell bracket and press SHIFT-Enter.

This initialization assumes that the Descarta2D software has been copied into one of the standard directories for AddOns which are on the Mathematica search path, $Path.

<<Descarta2D`

Solution

Create the three circles.

Clear[r1,r2,r3,a,b,d];
c1=Circle2D[{0,0},r1];
c2=Circle2D[{d,0},r2];
c3=Circle2D[{a,b},r3];

Find the intersection point of the external tangents for the first pair.

t12=TangentLines2D[c1,c2];
p12=Point2D[t12[[1]]//Simplify,
            t12[[2]]//Simplify] //Simplify

Find the intersection point of the external tangents for the second pair.

t23=TangentLines2D[c2,c3];
p23=Point2D[t23[[1]]//Simplify,
            t23[[2]]//Simplify] //Simplify

Find the intersection point of the external tangents for the third pair.

t13=TangentLines2D[c1,c3];
p13=Point2D[t13[[1]]//Simplify,
            t13[[2]]//Simplify] //Simplify

The three points are collinear as shown by the zero value of the determinant.  The function IsCollinear2D produces the same result.

MakeRow$2D[Point2D[{x_,y_}]]:={x,y,1};
{Det[Map[MakeRow$2D,{p12,p23,p13}]] //Simplify,
IsCollinear2D[p12,p23,p13]}

Discussion

This is the plot of a numerical example.

Sketch2D[{c1,c2,c3,
          t12,p12,t13,p13,t23,p23,
          Line2D[p12,p23]} /.
   {r1->1,r2->2,r3->3,d->5,a->3,b->6},
   CurveLength2D->35]

Graphics saved as "monge01.eps".